home *** CD-ROM | disk | FTP | other *** search
/ Business Assistant / Business Assistant.iso / home / willrt / print.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  28.3 KB  |  484 lines
  1. 1  CLEAR ,49152:AML=49152:ON ERROR GOTO 9900:REM PRINT 5/1/86
  2. 5  KEY OFF:DEF SEG=&HB000:POKE 0,0:DEF SEG=&HB800:POKE 0,0:DEF SEG
  3. 6  CLS:PRINT"W":DEF SEG=&HB800:N1=PEEK(0):DEF SEG
  4. 7  CLS:PRINT"Q":DEF SEG=&HB800:N2=PEEK(0):DEF SEG
  5. 8  SHIFT=18:ICRT=0:IF N1=87 AND N2=81 THEN ICRT=1
  6. 9  CO1=7:CO2=0:CO3=0:COH=7:COB=7:IF ICRT>0 THEN CO1=15:CO2=0:CO3=7:COB=14:COH=14:SHIFT=0:WIDTH 40:GOSUB 4860
  7. 10  SHI=SHIFT:CLS:GOSUB 4870
  8. 12  FP=1:GOTO 10000
  9. 20  INPUT #1,I$:REM ENTRYPOINT 30!
  10. 30  IF LEN(I$)<2 THEN RETURN
  11. 32  AA1=VARPTR(I$):AD1=PEEK(AA1+1)+256*PEEK(AA1+2):ANUM=AD1+PEEK(AA1)-1:GOSUB 30000:POKE &HC082,LB:POKE &HC083,HB
  12. 34  CALL STRIP
  13. 36  L=PEEK(&HC084)+256*PEEK(&HC085)-AD1+2:IF L<1 THEN I$=X$:RETURN
  14. 38  I$=LEFT$(I$,L):RETURN
  15. 50  TC=TC+1:IF PR%<1 THEN RETURN
  16. 51  MA%=0:IF MX=MX% THEN MA%=MA
  17. 53  GOSUB 70:PRINT STRING$(MA%," ")+PR$;:IF RF<1 THEN PRINT
  18. 54  IF PS%=1 THEN LPRINT STRING$(MA%," ")+PR$;:IF RF<1 THEN LPRINT
  19. 55  RETURN
  20. 60  TC=TC+1:GOSUB 70:IF PR%>0 THEN  PRINT
  21. 62  IF PR%>0 AND PS%=1 THEN LPRINT " "
  22. 65  RETURN
  23. 70  IF PS%<>3 OR PR%<1 OR CSRLIN <23 THEN RETURN
  24. 72  PG%=PG%+1:I$="Screen "+STR$(PG%):GOSUB 15400
  25. 74  CLS:RETURN
  26. 80  MS%=78:PS%=3:PA%=1:MM=24:MA=0:RETURN
  27. 100  MS%=68:Y%=1:PG%=0:LP%=0:ML=57:MM=ML+3:PS%=1:MA=5:IF PF>0 THEN GOSUB 80:GOTO 150
  28. 110  GOSUB 1250
  29. 120  GOSUB 1050:GOSUB 1100
  30. 130  GOSUB 1150:GOSUB 1300:IF I$=N$ THEN 110
  31. 150  ML=MM-3:DM%=16:MX%=MS%:HH%=MX%:H2%=HH%/2:LL%=53
  32. 200  WIDTH 80:GOSUB 4870:CLS:PR%=1:GOSUB 7000:GOSUB 15080
  33. 300  TC=0:GOSUB 60:REM INTRO
  34. 310  WO$="WILL OF "+V$(1):I$=WO$:GOSUB 4600
  35. 320  GOSUB 60:GOSUB 60:I$=IN$+"I, "+V$(1)+", a resident of "+SN$+CY$
  36. 340  I$=I$+", declare that this is my will."
  37. 342  IF V$(20)<>NU$ AND V$(20)<>X$ THEN GOSUB 4499:I$=" My Social Security Number is: "+V$(20):GOSUB 8500:GOSUB 4510:GOTO 400
  38. 344  GOSUB 4500
  39. 400  NA=22:AC%=0:CL=TC:FOR IA=1 TO NA
  40. 404  IF IA<>4 THEN 420
  41. 410  IF G<1 OR V$(24)<>Y$ THEN 490
  42. 412  FOR IG=1 TO G:GOSUB 2600:AC%=AC%+1:TC=0:NO%=0:PR%=0:GOSUB 4300:GOSUB 5300
  43. 413  IF NO%>0 THEN AC%=AC%-1:GOTO 419
  44. 414  IF CL+TC>ML THEN GOSUB 15000
  45. 416  TC=0:PR%=1:GOSUB 4300:GOSUB 5300
  46. 418  CL=CL+TC
  47. 419  NEXT IG:GOTO 490
  48. 420  AC%=AC%+1:TC=0:NO%=0:PR%=0:GOSUB 4200
  49. 430  IF NO%>0 THEN AC%=AC%-1:GOTO 490
  50. 450  IF CL+TC>ML THEN GOSUB 15000
  51. 460  TC=0:PR%=1:GOSUB 4200
  52. 470  CL=CL+TC
  53. 490  NEXT IA
  54. 900  LP%=1:GOSUB 15000
  55. 910  GOSUB 15300
  56. 920  IF ICRT>0 THEN WIDTH 40:GOSUB 4870
  57. 922  GOSUB 4900:V=8:H=3:GOSUB 4800:PRINT "ENTER "DQ$P$DQ$" TO PRINT YOUR WILL":V=V+2:GOSUB 4800:PRINT"ENTER "DQ$S$DQ$" TO SEE YOUR WILL ON SCREEN"
  58. 928  F2%=4:GOSUB 1600
  59. 930  IF I$=Q$ THEN GOSUB 4900:V=10:H=10:GOSUB 4800:PRINT "SO LONG... "CHR$(2):SYSTEM
  60. 932  IF I$=P$ THEN PF=0:GOTO 100
  61. 933  IF I$=S$ THEN PF=1:GOTO 100
  62. 934  IF I$=RR$ THEN CHAIN"WW",11,ALL
  63. 936  GOTO 100
  64. 999  END
  65. 1050  GOSUB 4900:V=7:H=14:GOSUB 4800:PRINT TP$:V=V+2:H=3:GOSUB 4800:PRINT DQ$;C$;DQ$;" IF YOU HAVE CONTINUOUS PAPER":V=V+2:GOSUB 4800:PRINT DQ$S$DQ$" TO PRINT ONE SHEET AT A TIME";:F2%=1:GOSUB 1600:PA%=1:IF I$=S$ THEN PA%=0
  66. 1060  RETURN
  67. 1100  GOSUB 4900:V=8:H=2:GOSUB 4800:PRINT "CURRENTLY PRINTING "MM" LINES PER PAGE":V=V+3:GOSUB 4800:PRINT "ENTER "DQ$Y$DQ$" IF THIS IS OK";:V=V+2:H=H+6:GOSUB 4800:PRINT DQ$N$DQ$" TO CHANGE NUMBER OF LINES";
  68. 1120  F2%=2:GOSUB 1600:IF I$=Y$ THEN RETURN
  69. 1130  GOSUB 4900:V=10:H=3:GOSUB 4800:PRINT "ENTER NEW NUMBER OF LINES:";:BF=2:GOSUB 1400:BF=0:MM=VAL(I$):IF MM<10 OR MM>999 THEN GOSUB 1800:GOTO 1130
  70. 1140  ML=MM-3:GOTO 1100
  71. 1150  GOSUB 4900:V=4:H=4:GOSUB 4800:PRINT"WILLWRITER CURRENTLY ADDS"MA"SPACES"
  72. 1151  V=V+1:GOSUB 4800:PRINT"TO THE LEFT MARGIN SET ON YOUR"
  73. 1152  V=V+1:GOSUB 4800:PRINT"PRINTER."
  74. 1153  V=V+3:GOSUB 4800:PRINT"IF YOU WANT TO CHANGE THIS NUMBER"
  75. 1154  V=V+1:GOSUB 4800:PRINT"ENTER "DQ$N$DQ$" TO INCREASE OR DECREASE."
  76. 1156  V=V+2:GOSUB 4800:PRINT"ENTER "DQ$Y$DQ$" TO USE THE CURRENT"
  77. 1157  V=V+1:GOSUB 4800:PRINT"VALUE OF"MA"SPACES."
  78. 1160  V=16:GOSUB 4800:F2%=2:GOSUB 1600:IF I$=Y$ THEN RETURN
  79. 1170  GOSUB 4900:V=7:H=4:GOSUB 4800:PRINT "CURRENT LEFT MARGIN IS:";MA:V=10:H=4:GOSUB 4800:PRINT"ENTER NEW VALUE (0-20):":BF=1:GOSUB 1400:BF=0:MA%=VAL(I$):IF MA%<0 OR MA%>20 THEN GOSUB 1800:GOTO 1170
  80. 1180  MA=MA%:GOTO 1150
  81. 1190  H=3:V=VS:GOSUB 4800:PRINT T1$;T;T2$:V=V+3:GOSUB 4800:PRINT TP$DQ$Y$DQ$" if this is ok:";:V=V+2:H=H+6:GOSUB 4800:PRINT DQ$N$DQ$" to change to another value";:RETURN
  82. 1200  RETURN
  83. 1250  GOSUB 4900:V=3:H=3:GOSUB 4800:PRINT" DO YOU WISH TO HAVE YOUR WILL"
  84. 1252  V=V+2:GOSUB 4800:PRINT"NOTARIZED IN ADDITION TO HAVING IT":V=V+2:GOSUB 4800:PRINT"WITNESSED?":IF FF<1 THEN 1270
  85. 1260  V=V+2:GOSUB 4800:PRINT"(WE RECOMMEND THIS IF YOU LIVE IN":V=V+1:GOSUB 4800:PRINT SN$".)":V=V-1
  86. 1270  V=V+2:GOSUB 4800:GOSUB 4860:PRINT"->";:GOSUB 4870:PRINT"SEE MANUAL PART 11A FOR DETAILS.":V=V+3:GOSUB 4800:PRINT "ENTER:":V=V+1:GOSUB 4800:PRINT DQ$Y$DQ$" TO PRINT WILL WITH NOTARY FORM":V=V+1:GOSUB 4800
  87. 1280  PRINT DQ$N$DQ$" IF YOU DON'T WANT TO NOTARIZE":F2%=2:GOSUB 1600:GG=0:IF I$=Y$ THEN GG=1
  88. 1290  RETURN
  89. 1300  IF PS%=3 THEN PA%=1:MM=24
  90. 1310  GOSUB 4900:V=6:H=14:GOSUB 4800:PRINT "ENTER "DQ$Y$DQ$:V=V+2:H=6:GOSUB 4800:PRINT "WHEN YOUR PRINTER IS READY":V=V+2:GOSUB 4800:PRINT "ENTER "DQ$N$DQ$" TO RESET OPTIONS";
  91. 1320  F2%=2:GOSUB 1600:RETURN
  92. 1400  GOSUB 1790:V=22:H=28:IF BF>0 THEN V=10:IF BF>1 THEN H=30
  93. 1402  GOSUB 4800:PRINT UU$;UU$:GOSUB 4800:I$=X$
  94. 1410  T$=INKEY$:IF T$=X$ THEN 1410
  95. 1420  A=ASC(T$):IF A=13 THEN RETURN
  96. 1430  L=LEN(I$):IF A<32 THEN 1460
  97. 1440  IF L>1 THEN GOSUB 1800:GOTO 1410
  98. 1450  I$=I$+T$:PRINT T$;:GOTO 1410
  99. 1460  IF A=0 THEN AA=ASC(MID$(T$,2,1)):IF AA=75 OR AA=83 THEN A=8
  100. 1464  IF A<>8 OR L<1 THEN 1410
  101. 1470  IF L<2 THEN I$=X$:GOTO 1490
  102. 1480  I$=LEFT$(I$,L-1)
  103. 1490  GOSUB 1498:PRINT UU$;:GOSUB 1498:GOTO 1410
  104. 1498  V=CSRLIN:H=POS(1)-1:LOCATE V,H:RETURN:REM BACKSPACE
  105. 1600  H=2:V=CSRLIN+3:GOSUB 4800:PRINT ">ENTER "DQ$"R"DQ$" TO RETURN TO MAIN PROGRAM":V=V+1:GOSUB 4800:PRINT">ENTER "DQ$"Q"DQ$" TO QUIT":V=V+2:GOSUB 4800:PRINT" (DON'T FORGET "DQ$"RETURN"DQ$")":V=23
  106. 1601  I$=X$
  107. 1602  GOSUB 4800:GOSUB 1790:PRINT I$;
  108. 1604  T$=INKEY$:IF T$=X$ THEN 1604
  109. 1605  A=ASC(T$):IF A>90 THEN A=A-32:T$=CHR$(A)
  110. 1606  IF A=13 THEN 1610
  111. 1607  IF A=0 THEN AA=ASC(MID$(T$,2,1)):A=8:IF AA<>75 AND AA<>83 THEN 1604
  112. 1608  IF A=8 THEN GOSUB 4800:PRINT " ";:GOTO 1601
  113. 1609  I$=T$:GOTO 1602
  114. 1610  VA%=VAL(I$)
  115. 1620  IF F2%=0 OR I$=Q$ OR I$=RR$ OR I$= P$ THEN 1695
  116. 1630  IF F2%=1 AND (I$=C$ OR I$=S$) THEN 1695
  117. 1640  IF F2%=2 AND (I$=Y$ OR I$=N$) THEN 1695
  118. 1650  IF F2%=3 AND VA%>=0 AND VA%<7 THEN 1695
  119. 1660  IF F2%=4 AND (I$=S$ OR I$=Q$ OR I$=RR$ OR I$=P$) THEN 1695
  120. 1665  IF F2%=5 AND (I$=S$ OR I$=P$) THEN 1695
  121. 1670  GOSUB 1800:GOTO 1601
  122. 1680  IF I$<>CR$ THEN GOSUB 1498
  123. 1682  PRINT SP$;:GOSUB 1498:RETURN
  124. 1695  IF I$=Q$ THEN SYSTEM
  125. 1696  IF I$=RR$ THEN CHAIN"WW",11,ALL
  126. 1699  RETURN
  127. 1790  DEF SEG =0:POKE 1050,PEEK(1052):DEF SEG:RETURN
  128. 1800  BEEP:RETURN
  129. 2000  GOSUB 4700:OPEN "WD" FOR INPUT AS #1:INPUT #1,FI%:INPUT #1,CH%:INPUT #1,D: INPUT #1,G:INPUT #1,SN$:INPUT #1,FF:INPUT #1,CP
  130. 2030  FOR I=1 TO NV:GOSUB 20:V$(I)=I$:NEXT:INPUT #1,PF:CLOSE #1:IF SN$="CALIFORNIA" THEN CA%=1
  131. 2032  IF V$(13)<>NU$ AND V$(13)<> X$ THEN CY$=QZ$+V$(13)
  132. 2040  DC%=0:IF LEFT$(SN$,4)="DIST" THEN DC%=1:SN$ ="THE DISTRICT OF COLUMBIA":RETURN
  133. 2050  SN$=SO$+SN$:RETURN
  134. 2500  F$="F."+MID$(STR$(FF%),2,1):LF%=38:OPEN F$ AS #1 LEN=LF%:FIELD #1,LF% AS TI$:FOR I=1 TO M%
  135. 2510  GET #1,I:I$=TI$:GOSUB 30:IF FF%=1 THEN CH$(I)=I$
  136. 2520  IF FF%=2 THEN DI$(I)=I$
  137. 2530  NEXT I:CLOSE #1:RETURN
  138. 2600  IF IG<1 OR IG>G THEN RETURN
  139. 2610  F$="F.0"
  140. 2620  OPEN F$ AS #1 LEN=240:FIELD #1,240 AS TI$
  141. 2660  IG%=3*IG-2
  142. 2700  GET #1,IG%:I$=TI$:GOSUB 30:GD$=I$:GET #1,IG%+1:I$=TI$:GOSUB 30:GN$=I$:GET #1,IG%+2:I$=TI$:GOSUB 30:GA$=I$
  143. 2720  CLOSE #1:RETURN
  144. 4200  GOSUB 4300:ON IA GOSUB 5000,5100,5200,5300,6400,5500,5740,6600,5800,5900,6100,6500,5700,6700,6720,6740,6760,6800,6950,6000,7200,6200
  145. 4210  RETURN
  146. 4300  GOSUB 60:I$=X$:AC=AC%:REM ORDINALS
  147. 4310  A1%=INT(AC/10):A0%=AC-10*A1%
  148. 4320  IF A1%<2 THEN 4330
  149. 4322  I$=I$+N2$(A1%):IF A0%=0 THEN I$=I$+IE$:GOTO 4350
  150. 4324  I$=I$+Y$+"-"+N1$(A0%):IF A0%<4 THEN GOTO 4350
  151. 4326  I$=I$+TH$:GOTO 4350
  152. 4330  I$=I$+N1$(AC):IF (A0%<4 AND A1%=0) THEN GOTO 4350
  153. 4332  I$=I$+TH$
  154. 4350  I$=IN$+I$+": ":RETURN
  155. 4400  REM FRAME
  156. 4410  V=1:H=1:GOSUB 4800:PRINT FR$;:FOR I=1 TO 23:V=I:H=1:GOSUB 4800:PRINT "|";:H=40:GOSUB 4800:PRINT "|";:NEXT I:V=24:H=1:GOSUB 4800:PRINT FR$;:GOSUB 4810:RETURN
  157. 4499  RF%=1
  158. 4500  MX=MX%:REM PRINT I$
  159. 4510  RF=0:TE$=LEFT$(I$,MX)
  160. 4525  IF I$=X$ OR I$=SP$ THEN 4590
  161. 4530  IF LEN(I$)<=MX THEN PR$=I$:RF=RF%:GOSUB 50:GOTO 4590
  162. 4532  DM=MX-DM%:IF DM<1 THEN DM=1
  163. 4540  II=0:FOR I=MX TO DM STEP -1:IF MID$(TE$,I,1)=SP$ THEN II=I:I=DM
  164. 4545  NEXT
  165. 4550  IF II>0 THEN 4570
  166. 4552  IF LEN(TE$)<DM% THEN GOSUB 60:GOTO 4500:REM DON'T HYPH SHORTIES
  167. 4555  PR$=TE$+"-":GOSUB 50
  168. 4560  IF LEN(I$)<=MX THEN 4590
  169. 4565  I$=MID$(I$,MX+1,255):GOTO 4580
  170. 4570  PR$=LEFT$(I$,II-1):GOSUB 50:I$=MID$(I$,II+1,255)
  171. 4580  IF LEFT$(I$,1)=SP$ THEN I$=MID$(I$,2,255):GOTO 4580
  172. 4585  MX=MX%:GOTO 4510
  173. 4590  IF RF%>0 THEN MX=MX%-LEN(PR$)-1:IF MX<1 THEN MX=1
  174. 4592  RF%=0:RETURN
  175. 4600  LL=LEN(I$):IF LL>HH% THEN GOSUB 4500:RETURN:REM CENT
  176. 4610  HH=(HH%-LL)/2-1
  177. 4620  IF HH<1 THEN HH=1
  178. 4630  IF HH>H2% THEN HH=H2%
  179. 4640  PR$=LEFT$(BL$,HH)+I$:GOSUB 50:RETURN
  180. 4650  TS$=I$:REM ;
  181. 4660  LT%=LEN(TS$):IF LT%<1 THEN RETURN
  182. 4662  IM%=0:FOR IJ=1 TO LT%:IF MID$(TS$,IJ,1)=";" THEN IM%=IJ:IJ=LT%
  183. 4664  NEXT IJ:IF IM%<1 THEN I$=TS$:GOSUB 4600:RETURN
  184. 4670  IF IM%>1 THEN 4680
  185. 4672  GOSUB 60:IF LT%>1 THEN TS$=RIGHT$(TS$,LT%-1):GOTO 4660
  186. 4674  RETURN
  187. 4680  I$=LEFT$(TS$,IM%-1):GOSUB 4600
  188. 4682  IF LEN(TS$)>IM% THEN TS$=MID$(TS$,IM%+1,255):GOTO 4660
  189. 4690  RETURN
  190. 4700  V=10:H=11:GOSUB 4800:GOSUB 4880:PRINT ">";:GOSUB 4870:PRINT "DISK DRIVE IN USE";:GOSUB 4880:PRINT "<";:GOSUB 4870:RETURN
  191. 4710  V=12:H=3:GOSUB 4800:PRINT " PLEASE GET YOUR PRINTER READY NOW":RETURN
  192. 4800  IF ICRT<1 THEN LOCATE V,H+SHI:RETURN:REM VTAB,HTAB
  193. 4802  LOCATE V,H:RETURN
  194. 4810  LOCATE V,POS(1):RETURN:REM VTAB
  195. 4850  VT=CSRLIN:IF ICRT<1 THEN LOCATE VT,H+SHI:RETURN:REM HTAB
  196. 4851  LOCATE VT,H:RETURN
  197. 4860  COLOR CO2,CO1,CO3:RETURN:REM INVERSE
  198. 4870  COLOR CO1,CO2,CO3:RETURN:REM NORMAL
  199. 4880  COLOR CO1+16,CO2,CO3:RETURN:REM FLASH
  200. 4890  COLOR 1,CO2,CO3:RETURN:REM blue
  201. 4892  IF ICRT>0 THEN COLOR 14,CO2,CO3:RETURN:REM yellow
  202. 4894  RETURN
  203. 4900  CLS:GOSUB 4400:RETURN
  204. 4990  FOR I=1 TO 3000:NEXT:RETURN
  205. 5000  GOSUB 60:I$=I$+"I revoke all wills and codicils that I have previously made.":GOSUB 4500
  206. 5010  RETURN
  207. 5100  IF V$(3)<>Y$ THEN 8899
  208. 5110  I$=I$+"I am married":IF V$(4)<>X$ AND V$(4)<> NU$ THEN I$=I$+" to "+V$(4)
  209. 5112  GOSUB 8500:GOSUB 4500
  210. 5120  RETURN
  211. 5200  IF V$(5)<>Y$ OR CH%<1 THEN 8899
  212. 5202  IF PR%<=0 THEN RN%=0
  213. 5210  S1$=" one child":S2$=" is":IF RN%>1 THEN S1$=STR$(RN%)+" children":S2$="s are"
  214. 5220  I$=I$+"I have"+S1$+" now living, whose name"+S2$+": "
  215. 5230  GOSUB 4500:GOSUB 60:GOSUB 8000
  216. 5240  IF RN%<1 THEN 8899
  217. 5270  IF CH%=1 AND (CH$(1)<>X$ AND CH$(1)<>NU$) THEN RN%=1
  218. 5280  RETURN
  219. 5300  FR=0:IF LEN(GD$)<2 OR LEN(GN$)<2 OR GD$=NU$ OR GN$=NU$ THEN 8899
  220. 5310  IF PR%<1 THEN QQ$=RIGHT$(GD$,1):GD$=LEFT$(GD$,LEN(GD$)-1):IQ$=GN$:PQ$="+":GOSUB 8800:GN%=T:Q0$=RIGHT$(GN$,1):GN$=LEFT$(GN$,LEN(GN$)-1)
  221. 5320  GOSUB 60:T$="bequest of money or personal":IF QQ$="R" THEN T$="devise of real":
  222. 5330  I$=I$+"I make the following "+T$+" property.  I give":GOSUB 4500:GOSUB 60:I$=GD$:GOSUB 8600
  223. 5340  GOSUB 60:IF QQ$<>"R" THEN T=GN%:I$="to:":GOSUB 4500:GOTO 5344
  224. 5342  I$="together with any insurance on that property, and subject to any encumbrances on it at the time of my death, including any mortgage, deed of trust, and real property taxes and assessments, to":GOSUB 4500:GOSUB 60
  225. 5344  I$=GN$:GOSUB 8500:GOSUB 8600:GOSUB 60
  226. 5345  IF GA$=X$ OR GA$=NU$ THEN GA$="my residuary estate"
  227. 5350  IF GN%>0 THEN 5360
  228. 5352  IF Q0$="1" THEN GOSUB 8440:GOTO 5395
  229. 5354  GOSUB 8460:GOTO 5395
  230. 5360  IF Q0$="1" THEN GOSUB 8400:GOTO 5395
  231. 5362  GOSUB 8420
  232. 5395  GOSUB 60:I$=GA$:GOSUB 8500:GOSUB 4600:RETURN
  233. 5500  IQ$=V$(9):IF IQ$=X$ OR IQ$=NU$ THEN 8899
  234. 5502  GOSUB 60:PQ$="+":GOSUB 8800:GN%=T
  235. 5510  I$=I$+"I give my residuary estate, i.e. the rest of my property not otherwise specifically disposed of by this will or in any other manner, to:":GOSUB 4500:T=GN%:GOSUB 60
  236. 5512  I$=IQ$:GOSUB 8500:GOSUB 8600
  237. 5520  GOSUB 60:FR=0:IF V$(7)=X$ OR V$(7)=NU$ THEN FR=1
  238. 5522  IF GN%>0 THEN 5530
  239. 5524  IF V$(27)="1" THEN GOSUB 8440:GOTO 5540
  240. 5526  GOSUB 8460:GOTO 5540
  241. 5530  IF V$(25)="1" THEN GOSUB 8400:GOTO 5540
  242. 5532  GOSUB 8420
  243. 5540  IF FR<1 THEN GOSUB 60:I$=V$(7):GOSUB 8500:GOSUB 8600
  244. 5550  RETURN
  245. 5700  IF V$(17)=X$ OR V$(17)=NU$ THEN 8899
  246. 5712  I$=I$+"I name":GOSUB 4500:GOSUB 60:I$=V$(17):GOSUB 8600:GOSUB 60:I$="as personal representative (executor) of this will, to serve without bond.":GOSUB 4500
  247. 5716  IF V$(18)=X$ OR V$(18)=NU$ THEN RETURN
  248. 5720  GOSUB 60:I$="personal representative":T1$="B":GOSUB 7300:T1$=X$:GOSUB 4600:I$=V$(18):GOSUB 60:GOSUB 8600:GOSUB 60:I$=T2$:GOSUB 4500:RETURN
  249. 5740  GOSUB 60:IF CA%>0 THEN I$=I$+"I direct that my personal representative petition the court for an order to administer my estate under the provisions of the Independent Administration of Estates Act.":GOSUB 4500:RETURN
  250. 5741  I$=I$+"I hereby grant to my personal representative the following powers, to be exercised as he or she deems to be in the best interests of my estate:":GOSUB 4500
  251. 5742  I$=IN$+"1) To retain property without liability for loss or depreciation resulting from such retention.":GOSUB 4500
  252. 5744  I$=IN$+"2) To dispose of property by public or private sale, or exchange, or otherwise, and receive and administer the proceeds as a part of my estate.":GOSUB 4500:S1$=" bonds, notes, stocks or other securities"
  253. 5746  I$=IN$+"3) To vote stock, to exercise any option or privilege to convert"+S1$+" belonging to my estate into other"+S1$+", ":GOSUB 4499
  254. 5747  I$="and to exercise all other rights and privileges of a person owning similar property in his own right.":GOSUB 4510
  255. 5748  I$=IN$+"4) To lease any real property that may at any time form part of my estate.":GOSUB 4500
  256. 5750  I$=IN$+"5) To abandon, adjust, arbitrate, compromise, sue on or defend and otherwise deal with and settle claims in favor of or against my estate.":GOSUB 4500
  257. 5752  I$=IN$+"6) To continue or participate in any business which is a part of my estate, and to effect incorporation, dissolution or other change in the form of organization of the business.":GOSUB 4500
  258. 5754  I$=IN$+"7) To pay all just debts, and all taxes that may, by reason of my death, be assessed against my estate or any portion of it, whether passing by probate or not, ":GOSUB 4499
  259. 5755  I$="provided that such debts and taxes shall be first satisfied out of my residuary estate.":GOSUB 4510
  260. 5756  I$=IN$+"8) To do all other acts which in his or her judgment may be necessary or appropriate for the proper and advantageous management, investment and distribution of my estate.":GOSUB 4500
  261. 5758  GOSUB 60:S1$=" powers, authority and discretion ":I$=IN$+"The foregoing"+S1$+"granted to my personal representative are intended to be in addition to the"+S1$+"vested in him or her by operation of law ":GOSUB 4499
  262. 5759  I$="by virtue of his or her office, and may be exercised as often as is deemed necessary or advisable, without application to or approval by any court in any jurisdiction.":GOSUB 4510
  263. 5799  RETURN
  264. 5800  I$=I$+"If any beneficiary under this will in any manner, directly or indirectly, contests or attacks this will or any of its provisions, ":GOSUB 4499
  265. 5820  I$ = "any share or interest in my estate given to the contesting beneficiary under this will is revoked and shall be disposed of in the same manner provided herein as if that contesting beneficiary had predeceased me without issue."
  266. 5830  GOSUB 4510
  267. 5840  RETURN
  268. 5900  IF V$(3)<>Y$ THEN 8899
  269. 5910  I$=I$+"If my spouse and I should die simultaneously, or under such circumstances as to render it difficult or impossible to determine ":GOSUB 4499
  270. 5930  I$="who predeceased the other, I shall be conclusively presumed to have survived my spouse for purposes of this will.":GOSUB 4510
  271. 5940  RETURN
  272. 6000  IF V$(14)<>Y$ OR V$(15)=X$ OR V$(15)=NU$ THEN 8899
  273. 6010  I$=I$+"I wish to forgive the following debt(s) plus accrued interest as of the date of my death:":GOSUB 4500:GOSUB 60:I$=V$(15):GOSUB 8600:RETURN
  274. 6100  IF V$(6)<>Y$ OR V$(11)=X$ OR V$(11)=NU$ THEN 8899
  275. 6110  I$=I$+"If 45 days after my death there is no living person who is entitled by law to the custody of my minor child or children and who is available to assume such custody, I name":GOSUB 4500:GOSUB 60
  276. 6130  I$=V$(11):GOSUB 8600:GOSUB 60:I$="as guardian of my minor child or children.":GOSUB 4500
  277. 6140  IF V$(12)=X$ OR V$(12)=NU$ THEN 6195
  278. 6150  I$="guardian":T1$=X$:GOSUB 7300:GOSUB 4500:GOSUB 60:I$=V$(12):GOSUB 8600:GOSUB 60:I$=T2$:GOSUB 4500
  279. 6195  GOSUB 60:I$=IN$+"I request that no bond be required of any guardian named in this section.":GOSUB 4500:RETURN
  280. 6200  TD$="this _______day of ________________, 19___"
  281. 6201  I$=IN$+"I, "+V$(1)+", the testator, sign my name to this instrument, consisting of"+STR$(PG%+1)+" pages, including this page signed by me, "+TD$+".":GOSUB 4500
  282. 6202  I$=IN$:IF GG>0 THEN I$=I$+"Being first duly sworn, "
  283. 6204  I$=I$+"I hereby declare ":IF GG>0 THEN I$=I$+"to the undersigned authority "
  284. 6206  I$=I$+"that I sign and execute this instrument as my last will, that I sign it willingly, and that I execute it as my free and voluntary act for the purposes therein expressed.":GOSUB 4500
  285. 6208  S1$=" of the age of majority or otherwise legally empowered to make a will, and under no constraint or undue influence.":I$=IN$+"I declare that I am"+S1$:GOSUB 4500
  286. 6210  GOSUB 60:I$=LEFT$(UL$,40):GOSUB 4600:I$="(Signed)":GOSUB 4600
  287. 6300  IF PS%<>3 THEN GOSUB 60
  288. 6301  I$=IN$+"We, the witnesses, sign our names to this instrument, ":IF GG>0 THEN I$=I$+"being first duly sworn, "
  289. 6302  I$=I$+"and do hereby declare ":IF GG>0 THEN I$=I$+"to the undersigned authority, "
  290. 6304  I$=I$+"that the testator willingly signed and executed this instrument as the testator's last will.":GOSUB 4500
  291. 6310  I$ =IN$+"Each of us, in the presence of the testator, and in the presence of each other, hereby signs this will as witness to the testator's signing.":GOSUB 4500
  292. 6312  I$ =IN$+"To the best of our knowledge the testator is"+S1$:GOSUB 4500
  293. 6330  GOSUB 60
  294. 6345  IF PS%<>3 THEN GOSUB 60
  295. 6348  I$=IN$+"We declare under penalty of perjury, that the foregoing is true and correct, "+TD$:GOSUB 4500
  296. 6350  I$=LEFT$(UL$,18)+"residing at:"+UL$:I$=LEFT$(I$,MX%-MA-1):FOR J=1 TO 3:GOSUB 60:GOSUB 4600:GOSUB 60:NEXT J
  297. 6360  IF GG<1 THEN 6390
  298. 6370  GOSUB 60
  299. 6371  I$="*  FOR NOTARIZATION  *":GOSUB 4600:GOSUB 60
  300. 6372  I$=SO$+LEFT$(UL$,20)+QZ$+LEFT$(UL$,20):GOSUB 4500
  301. 6374  GOSUB 60:I$=IN$+"Subscribed, sworn to and acknowledged before me by":GOSUB 4500
  302. 6378  I$=V$(1):GOSUB 4600
  303. 6379  I$="and, "+LEFT$(UL$,24)+CS$+LEFT$(UL$,24)+", and "+LEFT$(UL$,24)+", witnesses, personally known to me (or proved to me on the basis of satisfactory evidence to be the persons), "+TD$:GOSUB 4500:GOSUB 60
  304. 6380  GOSUB 60
  305. 6381  I$="SIGNED:"+LEFT$(UL$,19):GOSUB 4600
  306. 6382  GOSUB 60:I$=LEFT$(UL$,30):GOSUB 4600:I$="Official Capacity of Officer":GOSUB 4600
  307. 6390  RETURN
  308. 6400  IF (V$(5)<>Y$ OR CH%<1) AND (V$(19)<>Y$ OR D<1) THEN 8899
  309. 6402  IF PR%<=0 THEN RN%=0
  310. 6410  S1$="I hereby leave $1.00 to ":IF RN%>1 THEN S1$=S1$+"each of the following persons:":S2$="these persons.":GOTO 6420
  311. 6412  S1$=S1$+"this person:":S2$="this person."
  312. 6420  I$=I$+S1$:GOSUB 4500:GOSUB 60
  313. 6425  IF CH%<1 OR V$(5)<>Y$ THEN 6460
  314. 6430  OF%=0:GOSUB 8000
  315. 6460  IF D<1 OR V$(19)<>Y$ THEN 6470
  316. 6461  FOR J=1 TO D:I$=DI$(J):IF I$=X$ OR I$=NU$ THEN 6469
  317. 6462  IF PR%<=0 THEN RN%=RN%+1:JJL=J
  318. 6464  IF J<JJL THEN I$=I$+CO$:GOTO 6468
  319. 6466  I$=I$+PD$
  320. 6468  GOSUB 4600
  321. 6469  NEXT J
  322. 6470  GOSUB 60:I$="This bequest is in addition to and not instead of any other gift, bequest, or devise that this will makes to "+S2$:GOSUB 4600
  323. 6490  IF D=1 AND CH%=0 AND (DI$(1)<>X$ AND DI$(1)<>NU$) THEN RN%=1
  324. 6492  IF CH%=1 AND D=0 AND (CH$(1)<>X$ AND CH$(1)<>NU$) THEN RN%=1
  325. 6495  IF RN%<1 THEN 8899
  326. 6499  RETURN
  327. 6500  I$=I$+"If any person not my child who receives property under this will is a minor at the time of distribution, I direct my personal representative to ":GOSUB 4499
  328. 6510  I$="distribute the property to the minor's custodian under the provisions of the Uniform Gifts to Minors Act, or the Uniform Transfers to Minors Act, enacted by "
  329. 6520  I$=I$+SN$+", if either is applicable.":GOSUB 4510:RETURN
  330. 6600  I$=I$+"I direct my personal representative to take all actions legally permissible to have the probate of my will done as simply and as free of court supervision ":GOSUB 4499
  331. 6610  I$="as possible under the laws of the state having jurisdiction over this will, including filing a petition in the appropriate court for the independent administration of my estate.":GOSUB 4510:RETURN
  332. 6700  IF V$(28)<>Y$ THEN 8899
  333. 6710  I$=I$+"All bequests and devises made in this will to any child listed immediately below shall be held in a separate trust for that child until that child reaches the age indicated:":GOSUB 4500
  334. 6712  GOSUB 60:OF%=1:GOSUB 8000:IF RN%<1 THEN V$(28)=X$:GOTO 8899
  335. 6715  GOSUB 60:I$="Any trusts established under this will shall be administered as described in the following sections.":GOSUB 4500:RETURN
  336. 6720  IF V$(28) <>Y$ THEN 8899
  337. 6722  I$=I$+"Trust Beneficiary Provisions":GOSUB 4500:GOSUB 60
  338. 6725  I$=IN$+"(a) Any trust income which is not distributed to a beneficiary by the trustee shall be accumulated and added to the principal of the trust administered for that beneficiary.":GOSUB 4500
  339. 6730  I$=IN$+"(b) As long as a trust beneficiary is under the age specified above, the trustee may distribute from time to time to or for the benefit of the beneficiary as much, or all, of the principal or net income ":GOSUB 4499
  340. 6732  I$="of the trust, or both, as the trustee deems necessary for the child's health, support, maintenance, and education.":GOSUB 4510
  341. 6734  I$=IN$+DQ$+"Education"+DQ$+" includes, but is not limited to, college, graduate, postgraduate, and vocational studies, and reasonably related living expenses.":GOSUB 4500
  342. 6735  I$=IN$+"(c) In deciding whether to make a distribution to the beneficiary, the trustee may take into account the beneficiary's other income, resources, and sources of support.":GOSUB 4500:RETURN
  343. 6740  IF V$(28)<>Y$ THEN 8899
  344. 6742  I$=I$+"Termination of Trust":GOSUB 4500:GOSUB 60
  345. 6745  I$=IN$+"The trust shall terminate when any of the following events occurs:":GOSUB 4500
  346. 6750  I$=IN$+"(a) the beneficiary reaches the age listed above;":GOSUB 4500
  347. 6755  I$=IN$+"(b) the beneficiary dies before the age specified above; or":GOSUB 4500:I$=IN$+"(c) the trust is exhausted through distributions allowed under these provisions.":GOSUB 4500
  348. 6757  I$=IN$+"If the trust terminates for reason (a), the remaining principal and accumulated net income of the trust shall pass to the beneficiary.":GOSUB 4500
  349. 6759  I$=IN$+"If the trust terminates for reason (b), the principal and accumulated net income of the trust shall pass under the beneficiary's will, or if there is no will, to his or her heirs.":GOSUB 4500:RETURN
  350. 6760  IF V$(28)<>Y$ THEN 8899
  351. 6761  I$=I$+"Powers of Trustee":GOSUB 4500:GOSUB 60
  352. 6762  I$=IN$+"In addition to other powers granted the trustee in this will, the trustee shall have:":GOSUB 4500
  353. 6764  I$=IN$+"(a) all the powers generally conferred on trustees by the laws of the state having jurisdiction over this trust;":GOSUB 4500
  354. 6768  I$=IN$+"(b) in respect to accumulated property and income in each trust, the powers conferred by this will on the personal representative; and":GOSUB 4500
  355. 6770  I$=IN$+"(c) the authority to hire and pay from the trust assets the reasonable fees of investment advisors, accountants, tax advisors, agents, attorneys,":GOSUB 4499
  356. 6775  I$=" and other assistants for the administration of the trust and for the management of any trust asset and for any litigation affecting the trust.":GOSUB 4510:RETURN
  357. 6800  IF V$(28)<>Y$ THEN 8899
  358. 6810  I$=I$+"Trust Administrative Provisions":GOSUB 4500:GOSUB 60
  359. 6820  I$=IN$+"(a) It is my intent that this trust be administered independent of court supervision to the maximum extent possible under the laws of the state having jurisdiction over this trust.":GOSUB 4500
  360. 6825  I$=IN$+"(b) The interests of trust beneficiaries shall not be transferable by voluntary or involuntary assignment or by operation of law and shall be free from the claims of creditors and from attachment, ":GOSUB 4499
  361. 6830  I$="execution, bankruptcy, or other legal process to the fullest extent permissible by law.":GOSUB 4510
  362. 6835  I$=IN$+"(c) Any trustee serving hereunder shall be entitled to reasonable compensation out of the trust assets for ordinary and extraordinary services, and for all ":GOSUB 4499
  363. 6840  I$="services in connection with the complete or partial termination of any trust created by this will.":GOSUB 4510
  364. 6845  I$=IN$+"(d) The invalidity of any provision of this trust instrument shall not affect the validity of the remaining provisions.":GOSUB 4500:RETURN
  365. 6950  IF V$(28)<>Y$ OR V$(29)=X$ OR V$(29)=NU$ THEN 8899
  366. 6960  I$=I$+"I name":GOSUB 4500:GOSUB 60
  367. 6965  I$=V$(29):GOSUB 8600:GOSUB 60:I$="to serve as trustee of any trust established under this will.":GOSUB 4500
  368. 6970  IF V$(30)=X$ OR V$(30)=NU$ THEN 6980
  369. 6975  I$="trustee":T1$=X$:GOSUB 7300:GOSUB 4500:GOSUB 60:I$=V$(30):GOSUB 8600:GOSUB 60:I$=T2$:GOSUB 4500
  370. 6980  RETURN
  371. 7000  GOSUB 60:I$ = "IMPORTANT NOTES": GOSUB 4600:GOSUB 60:I$ = "BEFORE"+E$:GOSUB 4500
  372. 7030  I$=IN$ + "Read your will carefully.  Is everything printed as you intended?  Do you understand the meaning of every word?":GOSUB 4499
  373. 7032  I$="  See Part 13 of the manual as well as the glossary (Part 15) if you don't completely understand all provisions.":GOSUB 4510
  374. 7040  GOSUB 60:I$ ="WHILE"+E$:GOSUB 4500
  375. 7060  I$=IN$+"* For your will to be valid you must be of sound mind and of the age specified by your state.  This is almost always 18.  See manual Part 2.":GOSUB 4500
  376. 7070  IF GG>0 THEN GOSUB 60:I$=IN$+"* You have chosen to notarize your will.  Therefore the signing and witnessing described below should be done in the presence of a notary.":GOSUB 4500
  377. 7080  GOSUB 60:I$=IN$+"* Your will must be witnessed by three witnesses, even though only two are legally required in many states. The witnesses should":GOSUB 4499
  378. 7082  I$=" be in your and each other's presence when you sign the will.  The witnesses need not read your will.":GOSUB 4510
  379. 7088  IF PS%=3 THEN I$=CP$:GOSUB 15400
  380. 7090  GOSUB 60:I$=IN$+"* You must say to the witnesses that you intend this to be your will.  Initial and date each page where indicated.  Then sign the last page in the presence of the witnesses. ":GOSUB 4499
  381. 7092  I$=" Use exactly the form of your name printed on the will.":GOSUB 4510
  382. 7094  I$=IN$+"The witnesses should state that they realize you intend this to be your will and they should then, in your presence, initial each page on the same line you ":GOSUB 4499
  383. 7096  I$="did.  Finally they should sign the last page in the space indicated for witnesses, and include their addresses.":GOSUB 4510
  384. 7100  IF PS%=3 THEN I$=CP$:GOSUB 15400
  385. 7120  GOSUB 60:I$="AFTER"+E$:GOSUB 4500:I$=IN$+"Keep your will in a safe place, where it can be readily found.  You may make photocopies.  However, only the signed original is legally valid and can be probated.":GOSUB 4500
  386. 7130  IF PS%<>3 THEN GOSUB 60
  387. 7132  I$=IN$+"If there are major changes in your life, you should make, sign, and have witnessed a new will.  Destroy the original of your old will and all copies. Changes that make it wise for you to make a new will include: ":GOSUB 4499
  388. 7134  I$="having or adopting a child, moving to another state, the death of anyone named in your will, a change of marital status, and a significant change in the property you own. See manual Part 12 for a complete list.":GOSUB 4510
  389. 7140  GOSUB 60:I$="KEEP UP TO DATE:":GOSUB 4500
  390. 7142  I$=IN$+"Fill out the WillWriter registration card in the manual and send it to Nolo Press at the address below.  If you do not have a copy of the manual include $49.95 for a full WillWriter package.":GOSUB 4500
  391. 7180  GOSUB 60:I$="WillWriter, Copyright 1985, 1986 by Legisoft, Inc.":GOSUB 4600
  392. 7190  I$="Nolo Press, 95O Parker St., Berkeley, CA 9471O":GOSUB 4600
  393. 7192  IF PS%=3 THEN I$=CP$:GOSUB 15400
  394. 7195  RETURN
  395. 7200  I$=I$+"Any bequest or devise made in this will to two or more beneficiaries shall be divided equally among them, unless unequal shares are specifically indicated.":GOSUB 4500:RETURN
  396. 7300  T2$="as "+I$:I$=IN$+"If this person or institution shall for any reason fail to qualify or cease to act as "+I$+", I name":IF T1$="B" THEN T2$=T2$+" (also without bond),"
  397. 7302  T2$=T2$+" instead.":RETURN
  398. 7400  I1$="If any beneficiary named to receive this property"+B$+"his or her share shall pass to the remaining surviving beneficiaries named above to receive this property. "
  399. 7404  I2$="If there are no such surviving beneficiaries, this property shall pass to:":RETURN
  400. 7410  I1$="If any child named to receive this property"+B$+"that child's living children shall take that child's share in equal shares. If a child named to receive this property"
  401. 7412  I2$=B$+"and leaves no children of his or her own, that child's share shall be divided in equal shares among any other surviving children named above to receive this property."
  402. 7414  I3$="If there are no such surviving children, the deceased child's share shall pass to:":RETURN
  403. 8000  IF PR%<=0 THEN RN%=0
  404. 8002  FOR J = 1 TO CH%:I$=CH$(J):GOSUB 8100:I$=T1$
  405. 8010  IF I$=X$ OR I$=NU$ OR I$=M$ OR (OF%>0 AND VAL(T2$)<18) THEN 8070
  406. 8020  IF OF%>0 THEN I$=I$+"...age:"+T2$
  407. 8030  IF PR%<=0 THEN RN%=RN%+1
  408. 8060  GOSUB 4600
  409. 8070  NEXT:TC$="my child":IF RN%>1 THEN TC$="the following of my children, in equal shares:"
  410. 8080  OF%=0:RETURN
  411. 8090  RETURN
  412. 8100  IQ$=I$:T2$="XX":PQ$=CHR$(1):GOSUB 8800:IF T<1 THEN T1$=I$:RETURN:REM DCOM
  413. 8110  IF T<2 THEN T1$=X$:RETURN
  414. 8120  T1$=LEFT$(I$,T-1):T2$=MID$(I$+"  ",T+1,2):RETURN
  415. 8200  I$="to:":RETURN
  416. 8300  PQ$=";":GOSUB 8800:IF T>1 THEN IQ$=LEFT$(IQ$,T-1)
  417. 8302  RETURN
  418. 8400  I$=IN$+"However, if any"+BE$+", that beneficiary's living children shall take that beneficiary's share, in equal shares.":GOSUB 4500
  419. 8402  I$=IN$+"If a"+BE$+" and leaves no children of his or her own, that beneficiary's share shall be divided in equal shares ":GOSUB 4499
  420. 8404  I$="among any other surviving beneficiaries named in this section to receive this property.":GOSUB 4510:IF FR>0 THEN RETURN
  421. 8406  I$=IN$+"If there are no such surviving named beneficiaries, the property shall pass to:":GOSUB 4500:RETURN
  422. 8420  I$=IN$+"However, if any"+BE$+", his or her share shall go to the remaining surviving beneficiaries, in equal shares.":GOSUB 4500:IF FR>0 THEN RETURN
  423. 8422  I$=IN$+"If there are no such surviving beneficiaries, this property shall go to:":GOSUB 4500:RETURN
  424. 8440  I$=IN$+"However, if the"+BE$+", that beneficiary's living children shall take the property, in equal shares.":GOSUB 4500:IF FR>0 THEN RETURN
  425. 8442  I$=IN$+"If the"+BE$+" and leaves no children of his or her own, the property shall go to:":GOSUB 4500:RETURN
  426. 8460  IF FR>0 THEN RETURN
  427. 8462  I$=IN$+"However, if the"+BE$+", the property shall go to:":GOSUB 4500:RETURN
  428. 8500  IF RIGHT$(I$,1)<>PD$ THEN I$=I$+PD$
  429. 8502  RETURN
  430. 8600  IQ$=I$
  431. 8602  PQ$="+":GOSUB 8800:IF T=1 THEN IQ$=MID$(IQ$,2):GOTO 8602
  432. 8604  IF T<1 THEN I$=IQ$:GOSUB 4650:RETURN
  433. 8606  I$=LEFT$(IQ$,T-1):IF LEN(IQ$)>T THEN IQ$=MID$(IQ$,T+1):GOTO 8608
  434. 8607  RETURN
  435. 8608  GOSUB 4650:GOSUB 60:I$="AND":GOSUB 4600:GOSUB 60:GOTO 8602
  436. 8800  T=INSTR(IQ$,PQ$):RETURN
  437. 8899  NO%=1:RETURN:REM VOID
  438. 9900  CHAIN"E
  439. 10000  M$=CHR$(1):BLOAD"DECOM.BIN",AML:STRIP=&HC08A
  440. 10002  BE$=" beneficiary named in this section to receive this property fails to survive me by 45 days"
  441. 10008  U$="---------------":FR$=LEFT$(U$+U$+U$,39):GOSUB 4400
  442. 10020  NV = 33:IN$ = "     ":UU$ = ".":E$=" YOU SIGN:":U$="---------------"
  443. 10024  UL$ = "_______________________________________________________________________________":SO$="THE STATE OF ":QZ$=", COUNTY OF "
  444. 10026  CS$ = ", ":MS$ = "my spouse":CP$ = "(Cover Page)"
  445. 10030   DIM V$(NV),N0$(9),N1$(20),N2$(9),CH$(17),DI$(17)
  446. 10032   FOR I = 1 TO 9: READ N0$(I): NEXT I
  447. 10033   DATA "ONE","TWO","THREE","FOUR","FIVE","SIX","SEVEN","EIGHT","NINE"
  448. 10034   FOR I = 1 TO 20: READ N1$(I): NEXT I
  449. 10035   DATA  "FIRST","SECOND","THIRD","FOUR","FIF","SIX","SEVEN","EIGH","NIN","TEN","ELEVEN","TWELF","THIRTEEN","FOURTEEN","FIFTEEN","SIXTEEN","SEVENTEEN","EIGHTEEN","NINETEEN","TWENTIE"
  450. 10036  FOR I=2 TO 9:READ N2$(I):NEXT I
  451. 10037  DATA "TWENT","THIRT","FORT","FIFT","SIXT","SEVENT","EIGHT","NINET"
  452. 10050  X$="":Q$="Q":P$="P":RR$="R":B$=" fails to survive me by 45 days, ":Y$="Y":N$="N":C$="C":CC$="c":S$ ="S":SS$="s":SP$=" ":DQ$=CHR$(34)
  453. 10052  IE$="IETH":TH$="TH":PD$=".":CO$=",":TP$="TYPE:":NU$="-NOT USED-"
  454. 10060  BL$="                                                                                "
  455. 10100  GOSUB 2000:IF PF<1 THEN GOSUB 4710
  456. 10102  IF CH%>0 THEN M%=CH%:FF%=1:GOSUB 2500
  457. 10104  IF D>0 THEN M%=D:FF%=2:GOSUB 2500
  458. 10106  IF G>0 THEN GOSUB 2600
  459. 10120  MS$=MS$+", "+V$(4)
  460. 10290  GOTO 100
  461. 15000  REM START NEW PAGE
  462. 15010  IF CL>=ML THEN GOSUB 60:GOTO 15030
  463. 15020  FOR I=1 TO ML-CL+1
  464. 15022  PRINT"//":IF PS%=1 THEN LPRINT SPC(MA)"//"
  465. 15024  NEXT
  466. 15030  PR%=1:PG%=PG%+1:IF PS%=3 THEN 15035
  467. 15032  I$="Page"+STR$(PG%):IF LP%<1 THEN I$=I$+" Initials:______ ______ ______ ______ Date:_______"
  468. 15034  GOTO 15040
  469. 15035  I$="Screen"+STR$(PG%):GOSUB 15400:GOTO 15110
  470. 15040  GOSUB 4600
  471. 15080  IF PA%>0 AND PS%=3 THEN PRINT CHR$(12):GOTO 15110
  472. 15082  IF PA%>0  AND PS%=1 THEN LPRINT CHR$(12):GOTO 15110
  473. 15085  GOSUB 15300:CLS:IF LP%>0 THEN  RETURN
  474. 15090  GOSUB 4400:V=10:H=12:GOSUB 4800:PRINT "SET UP NEXT PAGE"
  475. 15092  V=V+3:H=8:GOSUB 4800:PRINT "PRESS "DQ$"RETURN"DQ$" WHEN READY...";:F2%=0:GOSUB 1600:PRINT:CLS
  476. 15110  IF LP% > 0 THEN  RETURN
  477. 15120  TC=0:IF PG%>0 THEN I$=WO$:GOSUB 4600
  478. 15122  CL=TC:IF PS%<>3 THEN RETURN
  479. 15130  GOSUB 4890:I$="Screen"+STR$(PG%+1):V=24:H=1:GOSUB 4800:PRINT I$;" BEING PROCESSED...";:V=1:GOSUB 4870:GOSUB 4800:RETURN
  480. 15300  PRINT:PRINT:RETURN
  481. 15400  GOSUB 4892:I$=" "+I$+"--press RETURN to go on   (R=return to Review/Modify Q=Quit)":V=24:H=1:GOSUB 4802:PRINT I$;:F2%=0:GOSUB 4870:H=59:IF ICRT>0 THEN H=77
  482. 15402  GOSUB 1601:CLS:RETURN
  483. 30000  HB=INT(ANUM/256):LB=ANUM-HB*256:RETURN
  484.